StringSortProof/all.bat at master · ComboxSoftDeveloper/StringSortProof · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
@echo off
cd /d %~dp0

rem ®«ë© ¯à®£®: áà ¢¥¨ï   § ¯¨áì, ¯®àï¤®ª ¯® ªã«ìâãà ¬, á¢¥àª
rem ®â¢¥â®¢, § ¬¥àë áà §ã   ç¥âëàñå à â ©¬ å ¨ § ¬¥àë   Stopwatch
rem ¢ ç¥âëàñå à¥¦¨¬ å.

dotnet --list-runtimes | findstr /c:"Microsoft.NETCore.App 8." >nul || goto nortm
dotnet --list-runtimes | findstr /c:"Microsoft.NETCore.App 9." >nul || goto nortm
dotnet --list-runtimes | findstr /c:"Microsoft.NETCore.App 10." >nul || goto nortm
dotnet --list-runtimes | findstr /c:"Microsoft.NETCore.App 11." >nul || goto no11

rem Žâçñâë ¯à®è«®£® ¯à®£®  ¥ ã¤ «ïîâáï á ¬¨, ¨ ¤¢  ¯à®£®  á¬¥è¨¢ îâáï.
if exist BenchmarkDotNet.Artifacts rd /s /q BenchmarkDotNet.Artifacts
if exist Bdn rd /s /q Bdn

dotnet build -c Release
if errorlevel 1 goto fail

for %%F in (net8.0 net9.0 net10.0 net11.0) do call :reports %%F
if errorlevel 1 goto fail

rem Ž¤¨ ¯à®£®   ç¥âëà¥ à â ©¬ . ‡ ¯ãáª ¨¤ñâ ¯®¤ net10.0: ¯®¤ net11.0
rem BenchmarkDotNet 0.15.8 ¯ ¤ ¥â   ¯à®¢¥àª¥, ¯®â®¬ã çâ® â ª®£® à â ©¬
rem ¥ § ¥â. –¥«¨ § ¤ ë áâà®ª ¬¨ ¢ BenchmarkConfig.
dotnet run -c Release -f net10.0 --no-build -- --filter * --artifacts Bdn
if errorlevel 1 goto fail

echo.
echo Gotovo:
echo   Bdn\results                  otchety BenchmarkDotNet: csv, md, html
echo   calls_netN.0.txt             sravnenij na zapis i sovpadenie poryadka
echo   orders_netN.0.txt            poryadok pri raznyh kulturah
echo   checks_netN.0.txt            sverka otvetov
echo   timing_netN.0.txt            zamer na Stopwatch
echo   timing_netN.0_nopgo.txt      to zhe bez dinamicheskogo profilya
echo   timing_netN.0_servergc.txt   to zhe na servernom sborshchike
echo   timing_netN.0_noicu.txt      to zhe bez ICU
pause
exit /b 0

:reports
set FW=%1
set EXE=bin\Release\%FW%\StringSortProof.exe
if not exist "%EXE%" exit /b 0

"%EXE%" calls > calls_%FW%.txt
"%EXE%" orders > orders_%FW%.txt

"%EXE%" checks > checks_%FW%.txt
if errorlevel 1 exit /b 1

"%EXE%" timing > timing_%FW%.txt

set DOTNET_TieredPGO=0
"%EXE%" timing > timing_%FW%_nopgo.txt
set DOTNET_TieredPGO=

set DOTNET_gcServer=1
"%EXE%" timing > timing_%FW%_servergc.txt
set DOTNET_gcServer=

rem ¥§ ICU áà ¢¥¨¥ áâà®ª ¨¤ñâ ¯® ¯®àï¤ª®¢ë¬ ¯à ¢¨« ¬: íâ® ®â¢¥ç ¥â
rem   ¢®¯à®á, áª®«ìª® ¨§ à §¨æë ¯à¨å®¤¨âáï ¨¬¥®   ªã«ìâãàã.
set DOTNET_SYSTEM_GLOBALIZATION_INVARIANT=1
"%EXE%" timing > timing_%FW%_noicu.txt
set DOTNET_SYSTEM_GLOBALIZATION_INVARIANT=

echo Done reports %FW%
exit /b 0

:nortm
echo Ne najden runtime 8, 9 ili 10.
pause
exit /b 1

:no11
echo Ne najden runtime 11. Zamery idut na chetyre celi, on obyazatelen.
pause
exit /b 1

:fail
echo Progon ostanovlen.
pause
exit /b 1